yt-dlp – скачивание видео/аудио с YouTube и не только (+таблица доступного качества)

[Misferado 2 530]

Привет! Собрал для себя (не без помощи DeepSeek) простенький UI для облегчения работы с программой yt-dlp
Может пригодится кому-то: демонстрация (видео YouTube)
Тут само меню + файлик для быстрого обновления программы: ссылка на Google Диск
Копируете URL видеоролика в буфер обмена и запускаете Меню.cmd

 

Важно:

• В папке с yt-dlp должен лежать deno.exe (x64 msvc) | это среда выполнения JavaScript, TypeScript и WebAssembly.
• Файлы Меню.cmd и Обновить программу.cmd должны лежать в папке с yt-dlp.exe
• Симлинк, либо сам файл ffmpeg.exe так же должен лежать рядом (нужен только ffmpeg.exe, он по ссылке в архиве ffmpeg-*.*-full_build.7z, в папке bin)
• Для корректной работы (скачивания видео 18+) нужно выгрузить cookie файлы со страницы YouTube в формате Netscape. Я пользовался расширением Get cookies.txt LOCALLY от kairi003 (зайти на youtube.com → тыкнуть на расширение → Export As). Файл с cookie нужно назвать cookies.txt и кинуть рядом с yt-dlp.exe.
• Качает всё на рабочий стол, папка dlp. Изменить директорию можете в самом начале файла (set "OUTPATH=%USERPROFILE%\Desktop\dlp").
• Иногда куки файлы отваливаются (нужны они только для 18+ видео). Так и не смог пофиксить. Решается повторной выгрузкой Cookie через расширение. Если кто знает, в чём проблема – дайте знать.
• Если заметили какие-то ошибки, либо есть предложения по улучшению – пишите, всё читаю.

Все действия вы выполняете на свой страх и риск. Никакой ответственности за сторонний софт, свой cmd файл и поведение Google не несу.

 

Вот так должно выглядеть содержимое папки:

 

Внутренности для интересующихся

@echo off
chcp 65001>nul
setlocal enabledelayedexpansion

:: визуал
title YouTube Downloader
color 0F

set "OUTPATH=%USERPROFILE%\Desktop\dlp"

for /f "delims=" %%i in ('powershell -NoProfile Get-Clipboard') do set "URL=%%i"

if not defined URL (
  echo Буфер обмена пуст или не содержит ссылку.
  pause
  exit /b 1
)

:: Проверка наличия cookies
if exist "cookies.txt" (
    set "COOKIES=--cookies cookies.txt"
) else (
    echo Предупреждение: cookies.txt не найден - работа без авторизации.
    set "COOKIES="
)

echo.
echo 0. Показать все доступные форматы
echo.
echo 1. Скачать видео+аудио в лучшем качестве
echo.
echo 2. 2160p
echo 3. 1440p
echo 4. 1080p
echo 5. 720p
echo 6. 480p
echo 7. 360p
echo 8. Скачать только аудио
echo.

choice /c 012345678 /n /m "Введите цифру: "
set "SEL=%errorlevel%"

:: Если выбран пункт 0 - показываем все форматы (с использованием cookies)
if "%SEL%"=="1" (
    echo.
    echo Список доступных форматов:
    echo ========================================
    yt-dlp %COOKIES% -F "%URL%"
    echo ========================================
    pause
    exit /b 0
)

:: Сброс переменных высоты и флагов
set "HEIGHT="
set "FORMAT="

:: Обработка выбора пользователя
if "%SEL%"=="2" (
    set "FORMAT=bestvideo[ext=mp4][height<=2160]+bestaudio[ext=m4a]/best[ext=mp4]/best"
    set "OUT_TAIL=-best"
)
if "%SEL%"=="3" set "HEIGHT=2160"
if "%SEL%"=="4" set "HEIGHT=1440"
if "%SEL%"=="5" set "HEIGHT=1080"
if "%SEL%"=="6" set "HEIGHT=720"
if "%SEL%"=="7" set "HEIGHT=480"
if "%SEL%"=="8" set "HEIGHT=360"

:: Формирование формата для выбранного качества
if not "%HEIGHT%"=="" set "FORMAT=bestvideo[ext=mp4][height<=%HEIGHT%]+bestaudio[ext=m4a]/best[ext=mp4]/best"

if "%SEL%"=="9" (
    set "AUDIO_EXTRACT=-x --audio-format opus --audio-quality 0"
    set "OUT_TAIL=-audio"
    set "FORMAT=bestaudio[ext=webm]/bestaudio"
) else (
    set "AUDIO_EXTRACT="
    if "%SEL%"=="2" (
        set "OUT_TAIL=-best"
    ) else if not "%SEL%"=="1" (
        set "OUT_TAIL=-%HEIGHT%"
    )
)

:: Скачивание
if "%SEL%"=="2" (
    echo Скачивание в лучшем доступном качестве...
) else if "%SEL%"=="9" (
    echo Скачивание аудио в формате OPUS...
) else if not "%SEL%"=="1" (
    echo Скачивание в качестве %HEIGHT%p...
)

yt-dlp %COOKIES% %AUDIO_EXTRACT% -o "%OUTPATH%\%%(title)s%OUT_TAIL%.%%(ext)s" -f "%FORMAT%" "%URL%"

if errorlevel 1 (
    echo Ошибка при скачивании.
) else (
    echo Скачивание завершено успешно!
)

endlocal
pause

 

[John_Doe 1 156]

скачивается отдельно видео и звук

 

[Misferado 2 530]

56 минут назад, John_Doe сказал:

скачивается отдельно видео и звук

 

На каком пересете?
Не замечал такого

   

 

 

ffmpeg.exe рядом с yt-dlp.exe должен лежать, а не в отдельной папке

[John_Doe 1 156]

26 минут назад, Misferado сказал:

ffmpeg.exe рядом должен лежать, а не в отдельной папке

 я вообще не понял где такого взять

который из них?

 

 

Изменено 10 часов назад пользователем John_Doe

[Misferado 2 530]

Только что, John_Doe сказал:

 я вообще не понял где такого взять

 

Из папки bin вытащить

[John_Doe 1 156]

[Misferado 2 530]

12 минут назад, John_Doe сказал:

который из них?

 

FFMpeg FullBuild нужен, который 153 мегабайта на твоём скрине

После распаковки будет весить 218 мегабайт (сам ffmpeg.exe), его кинуть рядом с yt-dlp.exe и всё должно заработать

Щас подправлю шапку

[John_Doe 1 156]

с этим файлом получилось. 

может есть смысл залить на гуглдиск готовый билд?

[Misferado 2 530]

3 минуты назад, John_Doe сказал:

с этим файлом получилось. 

может есть смысл залить на гуглдиск готовый билд?

 

Я то не против, просто не охота каждый раз вручную актуализировать билды на диске. ffmpeg, deno и yt-dlp постоянно обновляются, как ни крути.
Да и не хочется «воровать трафик» у первоисточника софта. Им же каждое скачивание засчитывается, что идёт в общий рейтинг популярности, а так же реакции и звёзды (Starred) никто ставить не будет, что тоже некрасиво по отношению к разработчикам.

[John_Doe 1 156]

полезная программа.

спасибо!

👍